qtwebkit: add patch for DBus based html5 video
[opendreambox.git] / meta-opendreambox / classes / package-transition.bbclass
1 #
2 # This class helps creating transitional packages. When a package
3 # was renamed from A to B, add TRANSITION_B = "A" to your recipe.
4 #
5 # https://wiki.debian.org/PackageTransition#Package_Transition
6 # https://wiki.debian.org/RenamingPackages#Transition_package_method
7 #
8
9 python __anonymous() {
10     if bb.data.inherits_class('native', d) or \
11        bb.data.inherits_class('cross', d) or \
12        bb.data.inherits_class('crosssdk', d) or \
13        bb.data.inherits_class('cross-canadian', d):
14         return
15
16     for p in (d.getVar('PACKAGES', True) or '').split():
17         for t in (d.getVar('TRANSITION_' + p, True) or '').split():
18             d.appendVar('PACKAGES', ' ' + t)
19             d.setVar('SUMMARY_' + t, 'Transitional package for ' + p)
20             d.setVar('DESCRIPTION_' + t, 'This is a transitional package for %s. It can safely be removed.' % p)
21             d.setVar('SECTION_' + t, 'oldlibs')
22             d.setVar('RDEPENDS_' + t, p)
23             d.setVar('FILES_' + t, '')
24             d.setVar('ALLOW_EMPTY_' + t, '1')
25
26             d.appendVar('RBREAKS_' + p, ' ' + t)
27             d.appendVar('RREPLACES_' + p, ' ' + t)
28             d.appendVar('RPROVIDES_' + p, ' ' + t)
29 }
30
31 def pkgtransvars(d):
32     return ' '.join(['TRANSITION_' + p for p in (d.getVar('PACKAGES', True) or '').split()])
33
34 populate_packages[vardeps] += "${@pkgtransvars(d)}"