opendreambox.conf: set fixed known good SRCREV for golang-x components
[opendreambox.git] / meta-opendreambox / conf / distro / opendreambox.conf
1 #@TYPE: Distribution
2 #@NAME: OpenDreambox
3 #@DESCRIPTION: Distribution configuration for OpenDreambox
4
5 #USER_CLASSES += "image-prelink"
6 INHERIT += "recipe_sanity"
7
8 DISTRO_NAME = "${DISTRO}"
9 DISTRO_VERSION = "2.5.0"
10
11 # meta/conf/distro/include/default-distrovars.inc
12 LOCALE_UTF8_ONLY ?= "1"
13 DISTRO_FEATURES_DEFAULT ?= "alsa argp bluetooth ext2 largefile usbhost wifi xattr nfs zeroconf pci \
14                             ppp smbfs systemd xinetd"
15 DISTRO_FEATURES_BACKFILL_CONSIDERED = "pulseaudio"
16 DISTRO_FEATURES_GCC ?= ""
17 DISTRO_FEATURES_GCC_mipsel ?= " mplt"
18 DISTRO_FEATURES_GFX ?= " opengl"
19 DISTRO_FEATURES_append = "${DISTRO_FEATURES_GCC}${DISTRO_FEATURES_GFX}"
20
21 # meta/conf/distro/defaultsetup.conf
22 PACKAGE_CLASSES ?= "package_deb"
23
24 # meta/recipes-core/sysvinit/sysvinit-inittab_2.88dsf.bb
25 SYSVINIT_ENABLED_GETTYS = ""
26
27 # meta/classes/image_types.bbclass
28 IMAGE_FSTYPES =+ "tar.xz"
29 XZ_COMPRESSION_LEVEL ?= ""
30
31 # meta/classes/image.bbclass
32 IMAGE_PKGTYPE ?= "deb"
33
34 # package versions
35 PREFERRED_VERSION_gnupg ?= "1.4.7"
36 PREFERRED_VERSION_xserver-nodm-init ?= "1.0"
37
38 require conf/go1.8-defaults.conf
39 GOLANG_X_CRYPTO_SRCREV = "4d70248d17d12d1edb7153434a74001c1540938b"
40 GOLANG_X_NET_SRCREV = "02ac38e2528ff4adea90f184d71a3faa04b4b1b0"
41 GOLANG_X_TEXT_SRCREV = "836efe42bb4aa16aaa17b9c155d8813d336ed720"
42 GOLANG_X_TOOLS_SRCREV = "3da34b1b520a543128e8441cd2ffffc383111d03"
43
44 PREFERRED_PROVIDER_jpeg ?= "libjpeg-turbo"
45 PREFERRED_PROVIDER_jpeg-native ?= "libjpeg-turbo-native"
46
47 PREFERRED_PROVIDER_virtual/fftw = "fftw"
48
49 PREFERRED_PROVIDER_virtual/update-alternatives = "dpkg"
50 PREFERRED_PROVIDER_virtual/update-alternatives-native = "dpkg-native"
51 PREFERRED_PROVIDER_virtual/nativesdk-update-alternatives = "nativesdk-dpkg"
52
53 VIRTUAL-RUNTIME_init_manager = "systemd"
54 VIRTUAL-RUNTIME_initscripts = "systemd-compat-units"
55 VIRTUAL-RUNTIME_update-alternatives = "update-alternatives-dpkg"
56
57 PACKAGECONFIG_pn-apt = "lzma opkg"
58
59 PACKAGECONFIG_pn-cogl-1.0 = "egl-null gles2"
60 EXTRA_OECONF_append_pn-cogl-1.0 = " --disable-introspection"
61
62 PACKAGECONFIG_pn-connman = "bluez l2tp openvpn pptp systemd vpnc wifi"
63
64 PACKAGECONFIG_pn-curl = "ssl zlib \
65         ${@bb.utils.contains('DISTRO_FEATURES', 'ipv6', 'ipv6', '', d)}"
66
67 PACKAGECONFIG_pn-dpkg = "update-alternatives xz"
68 PACKAGECONFIG_pn-dpkg-native = "update-alternatives xz"
69 PACKAGECONFIG_pn-nativesdk-dpkg = "update-alternatives xz"
70
71 PACKAGECONFIG_pn-glmark2 = ""
72
73 ORCPACKAGECONFIG = "orc"
74 ORCPACKAGECONFIG_mipsel = ""
75
76 PACKAGECONFIG_pn-gstreamer1.0-plugins-base = " \
77     ${@bb.utils.contains('DISTRO_FEATURES', 'x11', 'x11', '', d)} \
78     ${@bb.utils.contains('DISTRO_FEATURES', 'alsa', 'alsa', '', d)} \
79     ${ORCPACKAGECONFIG} ivorbis ogg theora vorbis pango"
80
81 PACKAGECONFIG_pn-gstreamer1.0-plugins-good = " \
82     ${@bb.utils.contains('DISTRO_FEATURES', 'x11', 'x11', '', d)} \
83     ${@bb.utils.contains('DISTRO_FEATURES', 'pulseaudio', 'pulseaudio', '', d)} \
84     ${ORCPACKAGECONFIG} cairo flac gdk-pixbuf gudev jpeg libpng soup speex taglib"
85
86 PACKAGECONFIG_pn-gstreamer1.0-plugins-bad = " \
87     ${@bb.utils.contains('DISTRO_FEATURES', 'wayland', 'wayland', '', d)} \
88     ${@bb.utils.contains('DISTRO_FEATURES', 'bluetooth', 'bluez', '', d)} \
89     ${@bb.utils.contains('DISTRO_FEATURES', 'directfb', 'directfb', '', d)} \
90     ${ORCPACKAGECONFIG} curl uvch264 neon sndfile \
91     hls sbc dash bz2 smoothstreaming \
92     opus faad libmms assrender rtmp"
93
94 PACKAGECONFIG_pn-gstreamer1.0-plugins-ugly = " \
95     ${ORCPACKAGECONFIG} a52dec lame mad mpeg2dec cdio"
96
97 PACKAGECONFIG_pn-ffmpeg = "avdevice avfilter avcodec avformat swresample swscale postproc"
98
99 PACKAGECONFIG_pn-kodi = "openglesv2"
100
101 PACKAGECONFIG_GL_pn-libsdl2 = "${@bb.utils.contains('DISTRO_FEATURES', 'opengl', 'gles2', '', d)}"
102
103 PACKAGECONFIG_pn-libunwind = "lzma"
104
105 PACKAGECONFIG_pn-mesa-demos = "drm osmesa freetype2 gbm egl gles2"
106
107 PACKAGECONFIG_pn-nfs-utils = "nfsv4 nfsv41 ipv6 tirpc"
108
109 PACKAGECONFIG_DISTRO_pn-qtbase = "icu sql-sqlite"
110 PACKAGECONFIG_FB_pn-qtbase = "linuxfb"
111 PACKAGECONFIG_GL_pn-qtbase = "${@bb.utils.contains('DISTRO_FEATURES', 'opengl', 'eglfs gles2', '', d)}"
112 EXTRA_QMAKEVARS_PRE_pn-qtbase = "QT_CONFIG-=eglfs_egldevice"
113 PACKAGECONFIG_pn-qtdeclarative = ""
114 PACKAGECONFIG_pn-qtwebkit = ""
115
116 PACKAGECONFIG_pn-samba = "systemd zeroconf"
117
118 PACKAGECONFIG_pn-systemd = "hostnamed ldconfig localed logind machined myhostname randomseed sysusers utmp xz"
119
120 PACKAGECONFIG_pn-weston = "${@bb.utils.contains('DISTRO_FEATURES', 'wayland', 'kms wayland', '', d)} \
121                            ${@bb.utils.contains('DISTRO_FEATURES', 'x11', 'x11', '', d)} \
122                            ${@bb.utils.contains('DISTRO_FEATURES', 'opengl', 'gles', '', d)} \
123                            ${@bb.utils.contains('DISTRO_FEATURES', 'pam', 'launch', '', d)}"
124
125 PACKAGECONFIG_pn-wpa-supplicant = "openssl"
126
127 PACKAGECONFIG_pn-xserver-xorg = "dri2 udev"
128
129 ROOT_HOME ?= "/root"
130
131 LICENSE_FLAGS_WHITELIST = "commercial"
132
133 # build some core libs with better compiler optimization for better performance
134 FULL_OPTIMIZATION_O3 = "-O3 -pipe ${DEBUG_FLAGS}"
135 FULL_OPTIMIZATION_pn-flac = "${FULL_OPTIMIZATION_O3}"
136 FULL_OPTIMIZATION_pn-jpeg = "${FULL_OPTIMIZATION_O3}"
137 FULL_OPTIMIZATION_pn-lame = "${FULL_OPTIMIZATION_O3}"
138 FULL_OPTIMIZATION_pn-liba52 = "${FULL_OPTIMIZATION_O3}"
139 FULL_OPTIMIZATION_pn-libdca = "${FULL_OPTIMIZATION_O3}"
140 FULL_OPTIMIZATION_pn-libgcrypt = "${FULL_OPTIMIZATION_O3}"
141 FULL_OPTIMIZATION_pn-libmad = "${FULL_OPTIMIZATION_O3}"
142 FULL_OPTIMIZATION_pn-libogg = "${FULL_OPTIMIZATION_O3}"
143 FULL_OPTIMIZATION_pn-libpng = "${FULL_OPTIMIZATION_O3}"
144 FULL_OPTIMIZATION_pn-libsamplerate = "${FULL_OPTIMIZATION_O3}"
145 FULL_OPTIMIZATION_pn-libvorbis = "${FULL_OPTIMIZATION_O3}"
146 FULL_OPTIMIZATION_pn-tremor = "${FULL_OPTIMIZATION_O3}"
147 FULL_OPTIMIZATION_pn-zlib = "${FULL_OPTIMIZATION_O3}"
148
149 # Drop unused PACKAGE_EXTRA_ARCHS
150 PACKAGE_EXTRA_ARCHS = "${TUNE_PKGARCH}"
151
152 PREMIRRORS ?= "\
153 bzr://.*/.*   http://dreamboxupdate.com/sources-mirror/ \n \
154 cvs://.*/.*   http://dreamboxupdate.com/sources-mirror/ \n \
155 git://.*/.*   http://dreamboxupdate.com/sources-mirror/ \n \
156 hg://.*/.*    http://dreamboxupdate.com/sources-mirror/ \n \
157 osc://.*/.*   http://dreamboxupdate.com/sources-mirror/ \n \
158 p4://.*/.*    http://dreamboxupdate.com/sources-mirror/ \n \
159 svn://.*/.*   http://dreamboxupdate.com/sources-mirror/ \n \
160 bzr://.*/.*   http://autobuilder.yoctoproject.org/sources/ \n \
161 cvs://.*/.*   http://autobuilder.yoctoproject.org/sources/ \n \
162 git://.*/.*   http://autobuilder.yoctoproject.org/sources/ \n \
163 hg://.*/.*    http://autobuilder.yoctoproject.org/sources/ \n \
164 osc://.*/.*   http://autobuilder.yoctoproject.org/sources/ \n \
165 p4://.*/.*    http://autobuilder.yoctoproject.org/sources/ \n \
166 svn://.*/.*   http://autobuilder.yoctoproject.org/sources/ \n"
167
168 MIRRORS =+ "\
169 ftp://.*/.*    http://dreamboxupdate.com/sources-mirror/ \n \
170 http://.*/.*   http://dreamboxupdate.com/sources-mirror/ \n \
171 https://.*/.*  http://dreamboxupdate.com/sources-mirror/ \n \
172 ftp://.*/.*    http://autobuilder.yoctoproject.org/sources/ \n \
173 http://.*/.*   http://autobuilder.yoctoproject.org/sources/ \n \
174 https://.*/.*  http://autobuilder.yoctoproject.org/sources/ \n"
175
176 DREAMBOX_FEATURES ??= ""