opendreambox.conf: disable buildhistory by default
[opendreambox.git] / meta-opendreambox / conf / distro / opendreambox.conf
1 #@TYPE: Distribution
2 #@NAME: OpenDreambox
3 #@DESCRIPTION: Distribution configuration for OpenDreambox
4
5 #USER_CLASSES += "image-prelink"
6 INHERIT += "recipe_sanity"
7
8 DISTRO_NAME = "${DISTRO}"
9 DISTRO_VERSION = "2.2.0"
10
11 # meta/conf/distro/include/default-distrovars.inc
12 DISTRO_FEATURES_DEFAULT ?= "alsa argp bluetooth ext2 largefile usbhost wifi xattr nfs zeroconf pci 3g \
13                             ppp smbfs systemd xinetd"
14 DISTRO_FEATURES_BACKFILL_CONSIDERED = "pulseaudio"
15 DISTRO_FEATURES_GCC ?= ""
16 DISTRO_FEATURES_GCC_mipsel ?= " mplt"
17 DISTRO_FEATURES_GFX ?= " opengl wayland x11"
18 DISTRO_FEATURES_GFX_mipsel ?= " opengl"
19 DISTRO_FEATURES_append = "${DISTRO_FEATURES_GCC}${DISTRO_FEATURES_GFX}"
20
21 # meta/recipes-core/sysvinit/sysvinit-inittab_2.88dsf.bb
22 SYSVINIT_ENABLED_GETTYS = ""
23
24 # meta/classes/image_types.bbclass
25 IMAGE_FSTYPES =+ "tar.xz"
26
27 # meta/classes/image.bbclass
28 IMAGE_PKGTYPE ?= "${@base_contains('PACKAGE_CLASSES', 'package_deb', 'deb', 'ipk', d)}"
29
30 # package versions
31 PREFERRED_VERSION_gnupg ?= "1.4.7"
32 PREFERRED_VERSION_openssl ?= "1.0.1e"
33 PREFERRED_VERSION_openssl_mipsel ?= "0.9.8za"
34 PREFERRED_VERSION_xserver-nodm-init ?= "1.0"
35
36 PREFERRED_PROVIDER_jpeg ?= "libjpeg-turbo"
37 PREFERRED_PROVIDER_jpeg-native ?= "libjpeg-turbo-native"
38
39 PREFERRED_PROVIDER_virtual/update-alternatives = "${@base_contains('PACKAGE_CLASSES', 'package_deb', 'dpkg', 'opkg-utils', d)}"
40 PREFERRED_PROVIDER_virtual/update-alternatives-native = "${@base_contains('PACKAGE_CLASSES', 'package_deb', 'dpkg-native', 'opkg-utils-native', d)}"
41 VIRTUAL-RUNTIME_update-alternatives = "${@base_contains('PACKAGE_CLASSES', 'package_deb', 'update-alternatives-dpkg', 'update-alternatives-opkg', d)}"
42
43 PACKAGECONFIG_pn-cogl-1.0 = "egl-kms egl-null \
44         ${@base_contains('DISTRO_FEATURES', 'opengl', 'gles2', '', d)} \
45         ${@base_contains('DISTRO_FEATURES', 'wayland', 'egl-wayland', '', d)} \
46         ${@base_contains('DISTRO_FEATURES', 'x11', 'egl-x11', '', d)}"
47
48 PACKAGECONFIG_pn-connman = "l2tp openvpn pptp vpnc \
49         ${@base_contains('DISTRO_FEATURES', '3g','3g', '', d)} \
50         ${@base_contains('DISTRO_FEATURES', 'bluetooth','bluetooth', '', d)} \
51         ${@base_contains('DISTRO_FEATURES', 'wifi','wifi wispr', '', d)}"
52
53 PACKAGECONFIG_pn-dpkg = "update-alternatives xz"
54
55 PACKAGECONFIG_pn-glmark2 = "gles2"
56
57 OPENDREAMBOX_GST_VERSION ?= "1.0"
58 OPENDREAMBOX_GST_VERSION_mipsel ?= "0.10"
59 PACKAGECONFIG_pn-gst-plugins-bad = "curl libmms musicbrainz orc"
60 PACKAGECONFIG_pn-gst-plugins-base = "orc \
61         ${@base_contains('DISTRO_FEATURES', 'x11', 'x11', '', d)}"
62 PACKAGECONFIG_pn-gst-plugins-good = "flac jpeg libpng orc soup zlib"
63 PACKAGECONFIG_pn-gst-plugins-ugly = "a52dec amrnb amrwb cdio lame mad mpeg2dec orc"
64
65 PACKAGECONFIG_pn-libunwind = "lzma"
66
67 PACKAGECONFIG_DISTRO_pn-qtbase = "icu sql-sqlite"
68 PACKAGECONFIG_FB_pn-qtbase = "linuxfb"
69 PACKAGECONFIG_GL_pn-qtbase = "${@base_contains('DISTRO_FEATURES', 'opengl', 'gles2', '', d)}"
70 PACKAGECONFIG_pn-qtdeclarative = ""
71 PACKAGECONFIG_pn-qtwebkit = ""
72
73 PACKAGECONFIG_pn-weston = "${@base_contains('DISTRO_FEATURES', 'wayland', 'kms wayland', '', d)} \
74                            ${@base_contains('DISTRO_FEATURES', 'x11', 'x11', '', d)} \
75                            ${@base_contains('DISTRO_FEATURES', 'opengl', 'gles', '', d)} \
76                            ${@base_contains('DISTRO_FEATURES', 'pam', 'launch', '', d)}"
77
78 PACKAGECONFIG_pn-xserver-xorg = "dri2 udev"
79
80 LICENSE_FLAGS_WHITELIST = "commercial"
81
82 # build some core libs with better compiler optimization for better performance
83 FULL_OPTIMIZATION_O3 = "-O3 -pipe ${DEBUG_FLAGS}"
84 FULL_OPTIMIZATION_pn-flac = "${FULL_OPTIMIZATION_O3}"
85 FULL_OPTIMIZATION_pn-jpeg = "${FULL_OPTIMIZATION_O3}"
86 FULL_OPTIMIZATION_pn-lame = "${FULL_OPTIMIZATION_O3}"
87 FULL_OPTIMIZATION_pn-liba52 = "${FULL_OPTIMIZATION_O3}"
88 FULL_OPTIMIZATION_pn-libdca = "${FULL_OPTIMIZATION_O3}"
89 FULL_OPTIMIZATION_pn-libgcrypt = "${FULL_OPTIMIZATION_O3}"
90 FULL_OPTIMIZATION_pn-libmad = "${FULL_OPTIMIZATION_O3}"
91 FULL_OPTIMIZATION_pn-libogg = "${FULL_OPTIMIZATION_O3}"
92 FULL_OPTIMIZATION_pn-libpng = "${FULL_OPTIMIZATION_O3}"
93 FULL_OPTIMIZATION_pn-libsamplerate = "${FULL_OPTIMIZATION_O3}"
94 FULL_OPTIMIZATION_pn-libvorbis = "${FULL_OPTIMIZATION_O3}"
95 FULL_OPTIMIZATION_pn-tremor = "${FULL_OPTIMIZATION_O3}"
96 FULL_OPTIMIZATION_pn-zlib = "${FULL_OPTIMIZATION_O3}"
97
98 # Drop unused PACKAGE_EXTRA_ARCHS
99 PACKAGE_EXTRA_ARCHS = "${TUNE_PKGARCH}"
100
101 PREMIRRORS ?= "\
102 bzr://.*/.*   http://dreamboxupdate.com/sources-mirror/ \n \
103 cvs://.*/.*   http://dreamboxupdate.com/sources-mirror/ \n \
104 git://.*/.*   http://dreamboxupdate.com/sources-mirror/ \n \
105 hg://.*/.*    http://dreamboxupdate.com/sources-mirror/ \n \
106 osc://.*/.*   http://dreamboxupdate.com/sources-mirror/ \n \
107 p4://.*/.*    http://dreamboxupdate.com/sources-mirror/ \n \
108 svk://.*/.*   http://dreamboxupdate.com/sources-mirror/ \n \
109 svn://.*/.*   http://dreamboxupdate.com/sources-mirror/ \n \
110 bzr://.*/.*   http://autobuilder.yoctoproject.org/sources/ \n \
111 cvs://.*/.*   http://autobuilder.yoctoproject.org/sources/ \n \
112 git://.*/.*   http://autobuilder.yoctoproject.org/sources/ \n \
113 hg://.*/.*    http://autobuilder.yoctoproject.org/sources/ \n \
114 osc://.*/.*   http://autobuilder.yoctoproject.org/sources/ \n \
115 p4://.*/.*    http://autobuilder.yoctoproject.org/sources/ \n \
116 svk://.*/.*   http://autobuilder.yoctoproject.org/sources/ \n \
117 svn://.*/.*   http://autobuilder.yoctoproject.org/sources/ \n"
118
119 MIRRORS =+ "\
120 ftp://.*/.*    http://dreamboxupdate.com/sources-mirror/ \n \
121 http://.*/.*   http://dreamboxupdate.com/sources-mirror/ \n \
122 https://.*/.*  http://dreamboxupdate.com/sources-mirror/ \n \
123 ftp://.*/.*    http://autobuilder.yoctoproject.org/sources/ \n \
124 http://.*/.*   http://autobuilder.yoctoproject.org/sources/ \n \
125 https://.*/.*  http://autobuilder.yoctoproject.org/sources/ \n"
126
127 DREAMBOX_FEATURES ??= ""
128 DREAMBOX_IMAGE_SIZE ??= "1024"
129
130 # for compatibility with rm_old_work.bbclass
131 WORKDIR = "${TMPDIR}/work/${MULTIMACH_TARGET_SYS}/${PN}/${PF}"
132
133 include conf/distro/include/seperatebuilddir.inc