dvdauthor: fix configure, inherit gettext and pkgconfig, depend on imagemagick
[opendreambox.git] / meta-opendreambox / recipes-connectivity / madwifi / madwifi-ng_r3314-20080131.bb
1 SUMMARY = "Linux driver for 802.11a/b/g universal NIC cards using Atheros chip sets"
2 LICENSE = "BSD-3-Clause | GPLv2"
3 LIC_FILES_CHKSUM = "file://COPYRIGHT;md5=58383ec8217e551da24db177e27a6ff2"
4 # versions of OpenWrt backfire (10.03)
5 SRCREV = "30414"
6 HAL_VERSION = "20090508"
7
8 SRC_URI = "http://snapshots.madwifi-project.org/madwifi-trunk/${BP}.tar.gz \
9            svn://svn.openwrt.org/openwrt/trunk/package/madwifi;module=patches \
10            http://mirror2.openwrt.org/sources/ath_hal-${HAL_VERSION}.tgz;name=hal \
11            file://fix-target-mips32.patch \
12            file://remove-wprobe.patch;apply=no \
13            file://fix-module-autoload.patch;apply=no \
14            file://fix-build-3.1.patch;apply=no \
15            file://fix-build-3.2.patch;apply=no \
16            file://ath-rate-ctlname.patch;apply=no \
17            file://set-affinity-hint.patch;apply=no \
18            file://workaround-high-interrupt-latency.patch;apply=no \
19            file://dm8000-nand-error-hack.patch;apply=no \
20            file://madwifi-smp-affinity"
21 SRC_URI[md5sum] = "2c7352cbbdac995de8c3bce5b80db5f2"
22 SRC_URI[sha256sum] = "0599c75b95ba63bdc554cb8124192e62c75fbeb71b9e8a5a7bc351c8e0666758"
23 SRC_URI[hal.md5sum] = "4ab7ae8bdb96c0be388c98bf8f92d5ca"
24 SRC_URI[hal.sha256sum] = "ced93d25aea7ee43807147a0269e69a072e718d59e7dab904bbe48b900409483"
25
26 S = "${WORKDIR}/${BP}"
27
28 inherit module
29
30 addtask postpatch after do_patch before do_configure
31
32 do_postpatch() {
33         rm -rf hal
34         cp -a ${WORKDIR}/ath_hal-${HAL_VERSION} hal
35         rm -f ${WORKDIR}/patches/104-autocreate_none.patch
36         rm -f ${WORKDIR}/patches/446-single_module.patch
37         rm -f ${WORKDIR}/patches/470-mac_addresss_from_ath5k_platform_data.patch
38         for i in ${WORKDIR}/patches/*.patch; do
39                 patch -p1 -i $i
40         done
41         patch -p1 -i ${WORKDIR}/remove-wprobe.patch
42         patch -p1 -i ${WORKDIR}/fix-module-autoload.patch
43         patch -p1 -i ${WORKDIR}/fix-build-3.1.patch
44         patch -p1 -i ${WORKDIR}/fix-build-3.2.patch
45         patch -p1 -i ${WORKDIR}/ath-rate-ctlname.patch
46         patch -p1 -i ${WORKDIR}/set-affinity-hint.patch
47         patch -p1 -i ${WORKDIR}/workaround-high-interrupt-latency.patch
48         patch -p1 -i ${WORKDIR}/dm8000-nand-error-hack.patch
49 }
50
51 EXTRA_OEMAKE = "KERNELPATH=${STAGING_KERNEL_DIR} KERNELRELEASE=${KERNEL_VERSION} TOOLPREFIX=${TARGET_PREFIX}"
52
53 do_compile() {
54         oe_runmake tools
55         unset CFLAGS CPPFLAGS CXXFLAGS LDFLAGS
56         oe_runmake modules
57 }
58 do_install() {
59         oe_runmake DESTDIR=${D} BINDIR=${sbindir} MANDIR=${mandir} install-tools
60         unset CFLAGS CPPFLAGS CXXFLAGS LDFLAGS
61         oe_runmake DESTDIR=${D} BINDIR=${sbindir} MANDIR=${mandir} install-modules
62         install -d ${D}${includedir}/${BPN}/include
63         install -m 644 include/compat.h ${D}${includedir}/${BPN}/include
64         install -d ${D}${includedir}/${BPN}/net80211
65         install -m 644 net80211/*.h ${D}${includedir}/${BPN}/net80211
66         install -d ${D}${sysconfdir}/network/if-pre-up.d
67         install -m 0755 ${WORKDIR}/madwifi-smp-affinity ${D}${sysconfdir}/network/if-pre-up.d
68         install -d ${D}${sysconfdir}/network/if-post-down.d
69         ln -sf ../if-pre-up.d/madwifi-smp-affinity ${D}${sysconfdir}/network/if-post-down.d
70 }
71
72 PACKAGES =+ "${PN}-modules ${PN}-tools"
73
74 RDEPENDS_${PN}-modules = "kernel-module-aes-generic"
75
76 FILES_${PN}-modules = "${sysconfdir}/network"
77 FILES_${PN}-tools = "${sbindir}/*"
78
79 KERNEL_MODULES_META_PACKAGE = "${PN}-modules"