force rebuild of madwifi and rtl8192 driver after kernel update
[opendreambox.git] / meta-opendreambox / recipes-connectivity / madwifi / madwifi-ng_r3314-20080131.bb
1 SRCREV = "30414"
2 PR = "${INC_PR}.8"
3
4 # versions of OpenWrt backfire (10.03)
5 HAL_VERSION = "20090508"
6
7 require madwifi-ng_r.inc
8
9 SRC_URI += " \
10         svn://svn.openwrt.org/openwrt/trunk/package/madwifi;module=patches \
11         http://mirror2.openwrt.org/sources/ath_hal-${HAL_VERSION}.tgz;name=hal \
12         file://fix-target-mips32.patch \
13         file://remove-wprobe.patch;apply=no \
14         file://fix-module-autoload.patch;apply=no \
15         file://fix-build-3.1.patch;apply=no \
16         file://fix-build-3.2.patch;apply=no \
17         file://ath-rate-ctlname.patch;apply=no \
18         file://set-affinity-hint.patch;apply=no \
19         file://workaround-high-interrupt-latency.patch;apply=no \
20         file://dm8000-nand-error-hack.patch;apply=no \
21         file://madwifi-smp-affinity \
22         "
23
24 SRC_URI[md5sum] = "2c7352cbbdac995de8c3bce5b80db5f2"
25 SRC_URI[sha256sum] = "0599c75b95ba63bdc554cb8124192e62c75fbeb71b9e8a5a7bc351c8e0666758"
26 SRC_URI[hal.md5sum] = "4ab7ae8bdb96c0be388c98bf8f92d5ca"
27 SRC_URI[hal.sha256sum] = "ced93d25aea7ee43807147a0269e69a072e718d59e7dab904bbe48b900409483"
28
29 addtask postpatch after do_patch before do_configure
30
31 do_postpatch() {
32         rm -rf hal
33         cp -a ${WORKDIR}/ath_hal-${HAL_VERSION} hal
34         rm -f ${WORKDIR}/patches/104-autocreate_none.patch
35         rm -f ${WORKDIR}/patches/446-single_module.patch
36         rm -f ${WORKDIR}/patches/470-mac_addresss_from_ath5k_platform_data.patch
37         for i in ${WORKDIR}/patches/*.patch; do
38                 patch -p1 -i $i
39         done
40         patch -p1 -i ${WORKDIR}/remove-wprobe.patch
41         patch -p1 -i ${WORKDIR}/fix-module-autoload.patch
42         patch -p1 -i ${WORKDIR}/fix-build-3.1.patch
43         patch -p1 -i ${WORKDIR}/fix-build-3.2.patch
44         patch -p1 -i ${WORKDIR}/ath-rate-ctlname.patch
45         patch -p1 -i ${WORKDIR}/set-affinity-hint.patch
46         patch -p1 -i ${WORKDIR}/workaround-high-interrupt-latency.patch
47 }
48
49 do_postpatch_append_dm8000() {
50         patch -p1 -i ${WORKDIR}/dm8000-nand-error-hack.patch
51 }
52
53 do_install_append() {
54         install -d ${D}/etc/network/if-pre-up.d
55         install -m 0755 ${WORKDIR}/madwifi-smp-affinity ${D}/etc/network/if-pre-up.d
56         install -d ${D}/etc/network/if-post-down.d
57         ln -sf ../if-pre-up.d/madwifi-smp-affinity ${D}/etc/network/if-post-down.d
58 }