meta-*: use SUMMARY instead of DESCRIPTION where appropriate (max. 80 chars)
[opendreambox.git] / meta-opendreambox / recipes-connectivity / vsftpd / vsftpd_2.3.5.bb
1 SUMMARY = "lightweight, efficient FTP server written for security"
2 HOMEPAGE = "https://security.appspot.com/vsftpd.html"
3 SECTION = "console/network"
4 LICENSE = "GPL-2.0-with-OpenSSL-exception"
5 LIC_FILES_CHKSUM = "file://COPYING;md5=a6067ad950b28336613aed9dd47b1271"
6 DEPENDS = "libcap openssl"
7 DEPENDS += "${@base_contains('DISTRO_FEATURES', 'pam', 'libpam', '', d)}"
8 PR = "r1"
9
10 SRC_URI = " \
11         https://security.appspot.com/downloads/${BP}.tar.gz \
12         file://vsftpd.xinetd.in \
13         file://01-builddefs.patch \
14         file://02-config.patch \
15         file://03-db-doc.patch \
16         file://04-link-local.patch \
17         file://05-whitespaces.patch \
18         file://06-greedy.patch \
19         file://07-utf8.patch \
20         file://08-manpage.patch \
21         file://09-s390.patch \
22         file://10-remote-dos.patch \
23 "
24 SRC_URI[md5sum] = "01398a5bef8e85b6cf2c213a4b011eca"
25 SRC_URI[sha256sum] = "d87ee2987df8f03e1dbe294905f7907b2798deb89c67ca965f6e2f60879e54f1"
26
27 S = "${WORKDIR}/${BP}"
28
29 inherit useradd xinetd
30
31 CFLAGS = "${TARGET_CFLAGS}"
32 CFLAGS += "-DVSF_BUILD_SSL=1"
33 CFLAGS += "${@base_contains('DISTRO_FEATURES', 'pam', '-DVSF_BUILD_PAM=1', '', d)}"
34
35 LIBS = "-lcap -lcrypt -lssl -lcrypto"
36 LIBS += "${@base_contains('DISTRO_FEATURES', 'pam', '-lpam', '', d)}"
37
38 LINK = "${TARGET_LDFLAGS}"
39
40 SECURE_CHROOT_DIR = "${datadir}/${BPN}/chroot"
41 RSA_CERT_FILE = "${sysconfdir}/ssl/private/${BPN}.pem"
42
43 do_configure() {
44         rm -f builddefs.h
45         touch builddefs.h
46         set_default() {
47                 NAME=$1
48                 VALUE=$2
49                 sed -e "s,^#\?${NAME}=.*,${NAME}=${VALUE}," -i vsftpd.conf
50         }
51         set_default listen NO
52         set_default listen_ipv6 NO
53         set_default anonymous_enable NO
54         set_default local_enable YES
55         set_default write_enable YES
56         set_default anon_upload_enable NO
57         set_default anon_mkdir_write_enable NO
58         set_default dirmessage_enable NO
59         set_default use_localtime YES
60         set_default xferlog_enable NO
61         set_default connect_from_port_20 YES
62         set_default chown_uploads NO
63         set_default nopriv_user vsftpd
64         set_default async_abor_enable YES
65         set_default ascii_upload_enable NO
66         set_default ascii_download_enable NO
67         set_default ftpd_banner "Welcome to the ${DISTRO_NAME} FTP service!"
68         set_default chroot_local_user NO
69         set_default chroot_list_enable NO
70         set_default ls_recurse_enable YES
71         set_default secure_chroot_dir "${SECURE_CHROOT_DIR}"
72         set_default rsa_cert_file "${RSA_CERT_FILE}"
73 }
74 do_compile() {
75         oe_runmake 'CFLAGS=${CFLAGS}' 'LIBS=${LIBS}' 'LINK=${LINK}'
76 }
77 do_install() {
78         install -d ${D}${sysconfdir}
79         install -m 644 vsftpd.conf ${D}${sysconfdir}
80         install -d ${D}${sbindir}
81         install -m 755 vsftpd ${D}${sbindir}/vsftpd
82         install -d ${D}${mandir}/man8
83         install -m 644 vsftpd.8 ${D}${mandir}/man8/vsftpd.8
84         install -d ${D}${mandir}/man5
85         install -m 644 vsftpd.conf.5 ${D}${mandir}/man5/vsftpd.conf.5
86         install -d ${D}${SECURE_CHROOT_DIR}
87 }
88
89 USERADD_PACKAGES = "${PN}"
90 USERADD_PARAM_${PN} = "--home-dir ${SECURE_CHROOT_DIR} --no-create-home --system --shell /bin/false --user-group vsftpd"