enigma2-plugins: bump srcrev again to fix compile
[opendreambox.git] / meta-opendreambox / recipes-dreambox / enigma2 / enigma2-plugins_3.999.bb
1 SUMMARY = "Additional plugins for Enigma2"
2 LICENSE = "Proprietary"
3 LIC_FILES_CHKSUM = "file://COPYING;md5=8e37f34d0e40d32ea2bc90ee812c9131"
4 DEPENDS = "enigma2 hdparm python-daap python-gdata python-mutagen python-pycrypto python-pyopenssl smartmontools streamripper"
5 SRCREV = "ebc83a66ac240033368d3e81f45a502323f6067f"
6
7 inherit autotools schwerkraft-git
8
9 EXTRA_OECONF = " \
10         BUILD_SYS=${BUILD_SYS} \
11         HOST_SYS=${HOST_SYS} \
12         STAGING_INCDIR=${STAGING_INCDIR} \
13         STAGING_LIBDIR=${STAGING_LIBDIR} \
14 "
15
16 PACKAGES_DYNAMIC = "enigma2-plugin-*"
17 PACKAGES += "${PN}-meta"
18
19 FILES_${PN} += "${datadir}/enigma2 ${datadir}/fonts"
20 FILES_${PN}-meta = "${datadir}/meta"
21
22 python populate_packages_prepend() {
23         enigma2_plugindir = bb.data.expand('${libdir}/enigma2/python/Plugins', d)
24         do_split_packages(d, enigma2_plugindir, '^(\w+/\w+)', 'enigma2-plugin-%s', '%s', recursive=True, match_path=True, prepend=True)
25         do_split_packages(d, enigma2_plugindir, '^(\w+/\w+).*/.*\.la$', 'enigma2-plugin-%s-dev', '%s (development)', recursive=True, match_path=True, prepend=True)
26         do_split_packages(d, enigma2_plugindir, '^(\w+/\w+).*/.*\.a$', 'enigma2-plugin-%s-staticdev', '%s (static development)', recursive=True, match_path=True, prepend=True)
27         do_split_packages(d, enigma2_plugindir, '^(\w+/\w+).*/\.debug/', 'enigma2-plugin-%s-dbg', '%s (debug)', recursive=True, match_path=True, prepend=True)
28         def parseControlFile(dir, d, package):
29                 import os
30                 src = open(dir + "/" + package.split('-')[-1] + "/CONTROL/control").read()
31                 for line in src.splitlines():
32                         name, value = line.strip().split(': ', 1)
33                         if name == 'Description':
34                                 d.setVar('DESCRIPTION_' + package, value)
35                         elif name == 'Depends':
36                                 d.setVar('RDEPENDS_' + package, ' '.join(value.split(', ')))
37                         elif name == 'Replaces':
38                                 d.setVar('RREPLACES_' + package, ' '.join(value.split(', ')))
39                         elif name == 'Conflicts':
40                                 d.setVar('RCONFLICTS_' + package, ' '.join(value.split(', ')))
41         srcdir = d.getVar('S', True)
42         for package in d.getVar('PACKAGES', True).split():
43                 if package.startswith('enigma2-plugin-') and not package.endswith('-dev') and not package.endswith('-dbg') and not package.endswith('-staticdev'):
44                         parseControlFile(srcdir, d, package)
45 }