dreambox-console-image: split-out nfo generation to own file
[opendreambox.git] / meta-opendreambox / recipes-dreambox / images / dreambox-console-image.inc
1 SUMMARY ?= "A Dreambox firmware image for headless systems"
2
3 # packages to build for the feed
4 DEPENDS = " \
5         gdb \
6         lsof \
7         ltrace \
8         strace \
9 "
10
11 python __anonymous() {
12     pkgtype = d.getVar('IMAGE_PKGTYPE', True)
13     if not oe.utils.inherits(d, 'package_%s' % pkgtype):
14         pn = d.getVar('PN', True)
15         raise bb.parse.SkipPackage("Unable to build %s without %s packages" % (pn, pkgtype))
16 }
17
18 BAD_RECOMMENDATIONS += " \
19     busybox-syslog \
20     libconnman-qt5-qmlplugins \
21     libnss-mdns \
22     qtbase-plugins \
23     qtdeclarative-plugins \
24     qtdeclarative-qmlplugins \
25     qtwebkit-qmlplugins \
26     udev-hwdb \
27     wpa-supplicant-passphrase \
28     xinetd \
29 "
30
31 # packages to drag into the image
32 IMAGE_INSTALL = " \
33     packagegroup-boot-systemd \
34     packagegroup-net-connman \
35     packagegroup-pkg-deb \
36     packagegroup-opendreambox-base \
37     packagegroup-opendreambox-dvbapi3 \
38 "
39
40 # enable online package management
41 IMAGE_FEATURES = "empty-root-password package-management"
42
43 # we don't want any locales, at least not in the common way.
44 IMAGE_LINGUAS = ""
45
46 # 512MB rootfs
47 IMAGE_ROOTFS_SIZE_ext4 = "524288"
48
49 inherit image
50
51 DREAMBOX_IMAGE_DATE = "${@d.getVar('DATETIME', True)[:-2]}"
52 DREAMBOX_IMAGE_DATE[vardepsexclude] = "DATETIME"
53 # 0: Release, 1: Experimental
54 DREAMBOX_IMAGE_TYPE ?= "1"
55 # e.g. 400 for release 4.0.0, if IMAGE_TYPE=0
56 DREAMBOX_IMAGE_VERSION ?= "000"
57
58 opendreambox_rootfs_postprocess() {
59     echo "version=${DREAMBOX_IMAGE_TYPE}${DREAMBOX_IMAGE_VERSION}${DREAMBOX_IMAGE_DATE}" > ${IMAGE_ROOTFS}${sysconfdir}/image-version
60 }
61
62 ROOTFS_POSTPROCESS_COMMAND += "opendreambox_rootfs_postprocess; "
63
64 require dreambox-image-nfo.inc