dreambox-console-image: don't install systemd-extra-utils by default
[opendreambox.git] / meta-opendreambox / recipes-dreambox / images / dreambox-console-image.inc
1 SUMMARY ?= "A Dreambox firmware image for headless systems"
2
3 # packages to build for the feed
4 DEPENDS = " \
5         gdb \
6         lsof \
7         ltrace \
8         strace \
9 "
10
11 python __anonymous() {
12     pkgtype = d.getVar('IMAGE_PKGTYPE', True)
13     if not oe.utils.inherits(d, 'package_%s' % pkgtype):
14         pn = d.getVar('PN', True)
15         raise bb.parse.SkipPackage("Unable to build %s without %s packages" % (pn, pkgtype))
16 }
17
18 BAD_RECOMMENDATIONS += " \
19     busybox-syslog \
20     libconnman-qt5-qmlplugins \
21     libnss-mdns \
22     qtbase-plugins \
23     qtdeclarative-plugins \
24     qtdeclarative-qmlplugins \
25     qtwebkit-qmlplugins \
26     systemd-extra-utils \
27     udev-hwdb \
28     wpa-supplicant-passphrase \
29     xinetd \
30 "
31
32 # packages to drag into the image
33 IMAGE_INSTALL = " \
34     packagegroup-boot-systemd \
35     packagegroup-net-connman \
36     packagegroup-pkg-deb \
37     packagegroup-opendreambox-base \
38     packagegroup-opendreambox-dvbapi3 \
39 "
40
41 # enable online package management
42 IMAGE_FEATURES = "empty-root-password package-management"
43
44 # we don't want any locales, at least not in the common way.
45 IMAGE_LINGUAS = ""
46
47 # 512MB rootfs
48 IMAGE_ROOTFS_SIZE_ext4 = "524288"
49
50 inherit image
51
52 DREAMBOX_IMAGE_DATE = "${@d.getVar('DATETIME', True)[:-2]}"
53 DREAMBOX_IMAGE_DATE[vardepsexclude] = "DATETIME"
54 # 0: Release, 1: Experimental
55 DREAMBOX_IMAGE_TYPE ?= "1"
56 # e.g. 400 for release 4.0.0, if IMAGE_TYPE=0
57 DREAMBOX_IMAGE_VERSION ?= "000"
58
59 opendreambox_rootfs_postprocess() {
60     echo "version=${DREAMBOX_IMAGE_TYPE}${DREAMBOX_IMAGE_VERSION}${DREAMBOX_IMAGE_DATE}" > ${IMAGE_ROOTFS}${sysconfdir}/image-version
61 }
62
63 ROOTFS_POSTPROCESS_COMMAND += "opendreambox_rootfs_postprocess; "
64
65 require dreambox-image-nfo.inc