enigma2: add patch to add missing SCALE_ imports to TemplatedMultiContent
[opendreambox.git] / meta-opendreambox / recipes-dreambox / images / dreambox-console-image.inc
1 SUMMARY ?= "A Dreambox firmware image for headless systems"
2
3 python __anonymous() {
4     pkgtype = d.getVar('IMAGE_PKGTYPE', True)
5     if not oe.utils.inherits(d, 'package_%s' % pkgtype):
6         pn = d.getVar('PN', True)
7         raise bb.parse.SkipPackage("Unable to build %s without %s packages" % (pn, pkgtype))
8 }
9
10 BAD_RECOMMENDATIONS += " \
11     libconnman-qt5-qmlplugins \
12     libnss-mdns \
13     qtbase-plugins \
14     qtdeclarative-plugins \
15     qtdeclarative-qmlplugins \
16     qtwebkit-qmlplugins \
17     systemd-extra-utils \
18     udev-hwdb \
19     wpa-supplicant-passphrase \
20     xinetd \
21 "
22
23 # packages to drag into the image
24 IMAGE_INSTALL = " \
25     packagegroup-boot-systemd \
26     packagegroup-net-connman \
27     packagegroup-pkg-deb \
28     packagegroup-opendreambox-base \
29     packagegroup-opendreambox-dvbapi3 \
30 "
31
32 # enable online package management
33 IMAGE_FEATURES = "empty-root-password package-management"
34
35 # we don't want any locales, at least not in the common way.
36 IMAGE_LINGUAS = ""
37
38 # 512MB rootfs
39 IMAGE_ROOTFS_SIZE_ext4 = "524288"
40
41 inherit image
42
43 DREAMBOX_IMAGE_DATE = "${@d.getVar('DATETIME', True)[:-2]}"
44 DREAMBOX_IMAGE_DATE[vardepsexclude] = "DATETIME"
45 # 0: Release, 1: Experimental
46 DREAMBOX_IMAGE_TYPE ?= "1"
47 # e.g. 400 for release 4.0.0, if IMAGE_TYPE=0
48 DREAMBOX_IMAGE_VERSION ?= "000"
49
50 opendreambox_rootfs_postprocess() {
51     echo "version=${DREAMBOX_IMAGE_TYPE}${DREAMBOX_IMAGE_VERSION}${DREAMBOX_IMAGE_DATE}" > ${IMAGE_ROOTFS}${sysconfdir}/image-version
52 }
53
54 ROOTFS_POSTPROCESS_COMMAND += "opendreambox_rootfs_postprocess; "
55
56 require dreambox-image-nfo.inc