lighttpd: add bbappend for 1.4.35
[opendreambox.git] / meta-opendreambox / recipes-extended / lighttpd / lighttpd_1.4.35.bbappend
1 DEPENDS = ""
2
3 SRC_URI += "file://lighttpd.conf.in"
4
5 EXTRA_OECONF = ""
6
7 PACKAGECONFIG ?= "pcre zlib \
8     ${@base_contains('DISTRO_FEATURES', 'ipv6', 'ipv6', '', d)} \
9     ${@base_contains('DISTRO_FEATURES', 'largefile', 'lfs', '', d)} \
10     ${@base_contains('DISTRO_FEATURES', 'xattr', 'attr', '', d)} \
11 "
12 PACKAGECONFIG[lfs] = "--enable-lfs,--disable-lfs"
13 PACKAGECONFIG[ipv6] = "--enable-ipv6,--disable-ipv6"
14 PACKAGECONFIG[mmap] = "--enable-mmap,--disable-mmap"
15 PACKAGECONFIG[libev] = "--with-libev,--without-libev,libev"
16 PACKAGECONFIG[mysql] = "--with-mysql,--without-mysql,mariadb"
17 PACKAGECONFIG[ldap] = "--with-ldap,--without-ldap,openldap"
18 PACKAGECONFIG[attr] = "--with-attr,--without-attr,attr"
19 PACKAGECONFIG[valgrind] = "--with-valgrind,--without-valgrind,valgrind"
20 PACKAGECONFIG[openssl] = "--with-openssl,--without-openssl,openssl"
21 PACKAGECONFIG[kerberos5] = "--with-kerberos5,--without-kerberos5"
22 PACKAGECONFIG[pcre] = "--with-pcre,--without-pcre,libpcre"
23 PACKAGECONFIG[zlib] = "--with-zlib,--without-zlib,zlib"
24 PACKAGECONFIG[bzip2] = "--with-bzip2,--without-bzip2,bzip2"
25 PACKAGECONFIG[fam] = "--with-fam,--without-fam,gamin"
26 PACKAGECONFIG[webdav-props] = "--with-webdav-props,--without-webdav-props,libxml2 sqlite3"
27 PACKAGECONFIG[webdav-locks] = "--with-webdav-locks,--without-webdav-locks,util-linux"
28 PACKAGECONFIG[gdbm] = "--with-gdbm,--without-gdbm,gdbm"
29 PACKAGECONFIG[memcache] = "--with-memcache,--without-memcache,memcached"
30 PACKAGECONFIG[lua] = "--with-lua,--without-lua,lua5.1"
31
32 do_install_append() {
33         rm -rf ${D}/www
34         sed -e 's,@localstatedir@,${localstatedir},g' -e 's,@sysconfdir@,${sysconfdir},g' \
35                 < ${WORKDIR}/lighttpd.conf.in > ${D}${sysconfdir}/lighttpd.conf
36 }
37
38 RDEPENDS_${PN} = "lighttpd-module-dirlisting \
39                   lighttpd-module-indexfile \
40                   lighttpd-module-staticfile"
41
42 RRECOMMENDS_${PN} = "lighttpd-module-access \
43                      lighttpd-module-accesslog"
44
45 FILESEXTRAPATHS_prepend := "${THISDIR}/${P}:"