update dm7080 hardware drivers (frontend / demux was broken in 20170409)
[opendreambox.git] / meta-opendreambox / recipes-multimedia / zvbi / zvbi_0.2.35.bb
1 SUMMARY = "Vertical Blanking Interval decoder (VBI)"
2 SECTION = "libs/multimedia"
3 LICENSE = "GPLv2+ & LGPLv2+"
4 LICENSE_${PN} = "GPLv2+"
5 LICENSE_${PN}-dev = "LGPLv2+"
6 LICENSE_libzvbi = "LGPLv2+"
7 LICENSE_libzvbi-chains = "LGPLv2+"
8 LIC_FILES_CHKSUM = "file://README;endline=31;md5=8e5fdf6998713f2beb4790827baad7e9"
9 DEPENDS = "libpng"
10
11 SRC_URI = "${SOURCEFORGE_MIRROR}/zapping/zvbi/${BP}.tar.bz2 \
12            file://0001-Fix-linker-errors-due-to-implicit-declaration-of-S_I.patch \
13            file://0002-fix-missing-lines-on-every-page-on-pro7-sat1.patch \
14            file://0003-fix-no-clock-updates.patch \
15            file://0004-fix-sky-not-working.patch \
16            file://0005-fix-top-navigation.patch \
17            file://0006-search-add-vbi_catch_page.patch \
18            file://0007-decode_timestamp-Disabled-check-to-work-around-inval.patch \
19            file://0008-caption_command-SF-bug-195-Mid-row-codes-are-set-at-.patch \
20            file://0009-parse_28_29-SF-bug-198-Faulty-logic-in-TTX-Level-2.5.patch \
21            file://0010-skip-data-with-wrong-framing-code.patch \
22            file://0011-fixed-memory-leak.patch"
23 SRC_URI[md5sum] = "95e53eb208c65ba6667fd4341455fa27"
24 SRC_URI[sha256sum] = "fc883c34111a487c4a783f91b1b2bb5610d8d8e58dcba80c7ab31e67e4765318"
25
26 inherit autotools gettext pkgconfig
27
28 PACKAGECONFIG ??= "${@bb.utils.contains('DISTRO_FEATURES', 'x11', 'x11', '', d)}"
29 PACKAGECONFIG[x11] = "--with-x,--without-x,virtual/libx11"
30
31 PACKAGES =+ "libzvbi libzvbi-chains"
32
33 FILES_libzvbi = "${libdir}/libzvbi${SOLIBS}"
34 FILES_libzvbi-chains = "${libdir}/libzvbi-chains${SOLIBS}"