meta-opendreambox/recipes-qt/libconnman-qt/libconnman-qte_git.bb

   1 DESCRIPTION = "Qt Library for ConnMan"
   2 HOMEPAGE = "https://github.com/nemomobile/libconnman-qt"
   3 SECTION = "qt/lib"
   4 LICENSE = "Apache-2.0"
   5 LIC_FILES_CHKSUM = "file://libconnman-qt/clockmodel.h;endline=8;md5=ea9f724050803f15d2d900ce3c5dac88"
   6 SRCREV = "f3313e0bda96985b647826ff40d26c2c0cdb1592"
   7 PV = "1.0.86+git${SRCPV}"
   8
   9 SRC_URI = "git://github.com/nemomobile/libconnman-qt.git;branch=master"
  10
  11 S = "${WORKDIR}/git"
  12
  13 inherit pkgconfig qt4e
  14
  15 EXTRA_QMAKEVARS_PRE += "CONFIG+=notests TARGET_SUFFIX=${QT_DIR_NAME}"
  16
  17 do_configure_prepend() {
  18     # Hack *.pro variables
  19     find ${S}/plugin/*.pro -exec sed -i -e 's,$$\[QT_INSTALL_IMPORTS\],${QT_IMPORTS_DIR},g' '{}' ';'
  20 }
  21 do_install() {
  22     oe_runmake install INSTALL_ROOT=${D}
  23     sed -e "s:^prefix=.*:prefix=${prefix}:" \
  24         -i ${D}${libdir}/pkgconfig/connman-${QT_DIR_NAME}.pc
  25 }
  26
  27 PACKAGES =+ "${PN}-plugin ${PN}-plugin-dbg"
  28
  29 RDEPENDS_${PN} = "connman"
  30 RDEPENDS_${PN}-plugin = "${PN}"
  31
  32 FILES_${PN} = " \
  33     ${libdir}/libconnman-qt*${SOLIBS} \
  34 "
  35 FILES_${PN}-dev = " \
  36     ${includedir}/connman-qt*/* \
  37     ${libdir}/libconnman-qt*${SOLIBSDEV} \
  38     ${libdir}/libconnman-qt*.prl \
  39     ${libdir}/pkgconfig/connman-qt*.pc \
  40 "
  41 FILES_${PN}-plugin = " \
  42     ${PLUGINS_TARGET}/qmldir \
  43     ${PLUGINS_TARGET}/lib*.so \
  44 "
  45 FILES_${PN}-plugin-dbg = " \
  46     ${PLUGINS_TARGET}/.debug \
  47     ${PLUGINS_TARGET}/.debug/* \
  48 "
  49
  50 QT_IMPORTS_DIR = "${libdir}/${QT_DIR_NAME}/imports"
  51 # the plugin target needs to be the same as 'target.path' and 'qmldir.path' in ${S}/plugin/plugin.pro
  52 PLUGINS_TARGET = "${QT_IMPORTS_DIR}/MeeGo/Connman"