qt4: update bbappend for 4.8.6
[opendreambox.git] / meta-opendreambox / recipes-qt / webkit / qtwebkit.inc
1 SUMMARY = "Qt port of WebKit"
2 HOMEPAGE = "http://trac.webkit.org/wiki/QtWebKit"
3 LICENSE = "LGPL-2.0 & LGPL-2.0+ & BSD-2-Clause"
4 LIC_FILES_CHKSUM = "file://Source/JavaScriptCore/COPYING.LIB;md5=d0c6d6397a5d84286dda758da57bd691 \
5                     file://Source/WebCore/LICENSE-APPLE;md5=4646f90082c40bcf298c285f8bab0b12 \
6                     file://Source/WebCore/LICENSE-LGPL-2;md5=36357ffde2b64ae177b2494445b79d21 \
7                     file://Source/WebCore/LICENSE-LGPL-2.1;md5=a778a33ef338abbaf8b8a7c36b6eec80 \
8                     file://Source/WebKit/LICENSE;md5=4646f90082c40bcf298c285f8bab0b12"
9 DEPENDS += "fontconfig sqlite3"
10
11 inherit lib_package pkgconfig
12
13 export WEBKITOUTPUTDIR = "${WORKDIR}/qtbuild"
14
15 PKGCONFIG_FILE = "${libdir}/pkgconfig/QtWebKit${QT_LIBINFIX}.pc"
16 PRL_FILE = "${libdir}/libQtWebKit${QT_LIBINFIX}.prl"
17 QMAKEARG = " \
18         INSTALL_HEADERS=${includedir}/${QT_DIR_NAME} \
19         INSTALL_LIBS=${libdir} \
20         QT_LIBINFIX=${QT_LIBINFIX} \
21 "
22
23 do_configure() {
24 }
25 do_compile() {
26     ${S}/Tools/Scripts/build-webkit --qt --qmake=${OE_QMAKE_QMAKE} --no-netscape-plugin --qmakearg="${QMAKEARG}"
27 }
28 do_install() {
29     oe_runmake -C ${WEBKITOUTPUTDIR}/Release install INSTALL_ROOT=${D}
30     # fix pkgconfig and prl files
31     sed -i -e s#-L${S}/lib##g \
32            -e s#-L${STAGING_LIBDIR}##g \
33            -e 's#STAGING_LIBDIR}#libdir}'#g \
34            -e s#-L${libdir}##g \
35            -e s#'$(OE_QMAKE_LIBS_X11)'#"${OE_QMAKE_LIBS_X11}"#g \
36            -e s#" -Wl,-rpath-link,${S}/lib"##g \
37            -e s#" -Wl,-rpath-link,${libdir}"##g \
38            -e 's#I/usr/include#Iincludedir}#g' \
39            -e 's#Iin#I${in#g' \
40            ${D}${PRL_FILE} ${D}${PKGCONFIG_FILE}
41     # fix pkgconfig files
42     sed -i -e 's:^prefix=.*:prefix=${prefix}:' \
43            -e 's:-L$(OE_QMAKE_LIBDIR_QT)::g' \
44            -e '/^Cflags:/s#{includedir}#{includedir} -I${includedir}/${QT_DIR_NAME} -DQT_SHARED#' \
45            ${D}${PKGCONFIG_FILE}
46     for name in QtCore QtGui QtNetwork; do
47            sed -i -e /Requires/s#"${name}"#"${name}${QT_LIBINFIX}"#g ${D}${PKGCONFIG_FILE}
48     done
49 }
50
51 FILES_${PN}-dev += "${PRL_FILE}"