enigma2: workaround for opkg <= 0.1.7+svnr455-r19.1, which caused tuxtxt.ttf to get...
[openembedded.git] / recipes / enigma2 / enigma2.bb
1 DESCRIPTION = "Enigma2 is an experimental, but useful framebuffer-based frontend for DVB functions"
2 MAINTAINER = "Felix Domke <tmbinc@elitedvb.net>"
3 DEPENDS = "jpeg libungif libmad libpng libsigc++-1.2 gettext-native \
4         dreambox-dvbincludes freetype libdvbsi++ python swig-native \
5         libfribidi libxmlccwrap libdreamdvd gstreamer gst-plugin-dvbmediasink \
6         gst-plugins-bad gst-plugins-good gst-plugins-ugly python-wifi"
7 RDEPENDS = "python-codecs python-core python-lang python-re python-threading \
8         python-xml python-fcntl gst-plugin-decodebin gst-plugin-decodebin2 python-stringold \
9         python-pickle gst-plugin-app \
10         gst-plugin-id3demux gst-plugin-mad gst-plugin-ogg gst-plugin-playbin \
11         gst-plugin-typefindfunctions gst-plugin-audioconvert gst-plugin-audioresample \
12         gst-plugin-wavparse python-netclient gst-plugin-mpegstream gst-plugin-selector \
13         gst-plugin-flac gst-plugin-dvbmediasink gst-plugin-mpegdemux \
14         gst-plugin-souphttpsrc gst-plugin-mpegaudioparse gst-plugin-subparse \
15         gst-plugin-apetag gst-plugin-icydemux gst-plugin-autodetect \
16         glibc-gconv-iso8859-15 ethtool"
17
18 GST_RTSP_RDEPENDS = "gst-plugin-udp gst-plugin-rtsp gst-plugin-rtp gst-plugin-rtpmanager"
19 GST_ALSA_RDEPENDS = "gst-plugin-alsa alsa-conf"
20 GST_MISC_RDEPENDS = "gst-plugin-matroska gst-plugin-qtdemux gst-plugin-vorbis gst-plugin-audioparsersbad"
21 GST_DVD_RDEPENDS = "gst-plugin-cdxaparse gst-plugin-cdio gst-plugin-vcdsrc"
22 GST_BASE_RDEPENDS = "${GST_ALSA_RDEPENDS} ${GST_MISC_RDEPENDS} ${GST_RTSP_RDEPENDS}"
23
24 RDEPENDS_append_dm7020 = " gst-plugin-ossaudio gst-plugin-ivorbisdec"
25 RDEPENDS_append_dm7025 = " ${GST_ALSA_RDEPENDS} gst-plugin-ivorbisdec"
26 RDEPENDS_append_dm800 = " ${GST_BASE_RDEPENDS} gst-plugin-ivorbisdec"
27 RDEPENDS_append_dm8000 = " ${GST_BASE_RDEPENDS} ${GST_DVD_RDEPENDS} gst-plugin-avi"
28 RDEPENDS_append_dm500hd = " ${GST_BASE_RDEPENDS} ${GST_DVD_RDEPENDS} gst-plugin-avi"
29 RDEPENDS_append_dm800se = " ${GST_BASE_RDEPENDS} ${GST_DVD_RDEPENDS} gst-plugin-avi"
30 RDEPENDS_append_dm7020hd = " ${GST_BASE_RDEPENDS} ${GST_DVD_RDEPENDS} gst-plugin-avi"
31
32 # 'forward depends' - no two providers can have the same PACKAGES_DYNAMIC, however both
33 # enigma2 and enigma2-plugins produce enigma2-plugin-*.
34 #DEPENDS += "enigma2-plugins"
35 #PACKAGES_DYNAMIC = "enigma2-plugin-*"
36
37 DESCRIPTION_append_enigma2-plugin-extensions-cutlisteditor = "enables you to cut your movies."
38 RDEPENDS_enigma2-plugin-extensions-cutlisteditor = "aio-grab"
39 DESCRIPTION_append_enigma2-plugin-extensions-graphmultiepg = "shows a graphical timeline EPG."
40 DESCRIPTION_append_enigma2-plugin-extensions-pictureplayer = "displays photos on the TV."
41 DESCRIPTION_append_enigma2-plugin-systemplugins-frontprocessorupdate = "keeps your frontprocessor up to date."
42 DESCRIPTION_append_enigma2-plugin-systemplugins-positionersetup = "helps you installing a motorized dish."
43 DESCRIPTION_append_enigma2-plugin-systemplugins-satelliteequipmentcontrol = "allows you to fine-tune DiSEqC-settings."
44 DESCRIPTION_append_enigma2-plugin-systemplugins-satfinder = "helps you to align your dish."
45 DESCRIPTION_append_enigma2-plugin-systemplugins-skinselector = "shows a menu with selectable skins."
46 DESCRIPTION_append_enigma2-plugin-systemplugins-videomode = "selects advanced video modes"
47 RDEPENDS_enigma2-plugin-extensions-dvdplayer = "libdreamdvd0"
48 RDEPENDS_enigma2-plugin-systemplugins-nfiflash = "twisted-web"
49 RDEPENDS_enigma2-plugin-systemplugins-softwaremanager = "twisted-web"
50 RCONFLICTS_enigma2-plugin-systemplugins-softwaremanager = "enigma2-plugin-systemplugins-configurationbackup enigma2-plugin-systemplugins-softwareupdate"
51 RREPLACES_enigma2-plugin-systemplugins-softwaremanager = "enigma2-plugin-systemplugins-configurationbackup enigma2-plugin-systemplugins-softwareupdate"
52 DESCRIPTION_append_enigma2-plugin-systemplugins-crashlogautosubmit = "automatically send crashlogs to Dream Multimedia"
53 RDEPENDS_enigma2-plugin-systemplugins-crashlogautosubmit = "twisted-mail twisted-names python-compression python-mime python-email"
54 DESCRIPTION_append_enigma2-plugin-systemplugins-cleanupwizard = "informs you on low internal memory on system startup."
55 DESCRIPTION_append_enigma2-plugin-extenstions-modem = "opens a menu to connect to internet via builtin modem."
56 RDEPENDS_enigma2-plugin-extensions-modem = "dreambox-modem-ppp-scripts ppp"
57 DESCRIPTION_append_enigma2-plugin-systemplugins-wirelesslan = "helps you configuring your wireless lan"
58 RDEPENDS_enigma2-plugin-systemplugins-wirelesslan = "wpa-supplicant wireless-tools python-wifi"
59 DESCRIPTION_append_enigma2-plugin-systemplugins-networkwizard = "provides easy step by step network configuration"
60
61 PN = "enigma2"
62 PR = "r2"
63
64 SRCDATE = "20101117"
65 #SRCDATE is NOT used by git to checkout a specific revision
66 #but we need it to build a ipk package version
67 #when you like to checkout a specific revision of e2 you need
68 #have to specify a commit id or a tag name in SRCREV
69
70 # if you want experimental use
71 ####################################################
72 BRANCH = "experimental"
73 PV = "experimental-git${SRCDATE}"
74 SRCREV = ""
75 ####################################################
76
77 SRC_URI = "git://git.opendreambox.org/git/enigma2.git;protocol=git;branch=${BRANCH};tag=${SRCREV}"
78
79 S = "${WORKDIR}/git"
80
81 FILES_${PN} += "${datadir}/fonts ${datadir}/keymaps"
82 FILES_${PN}-meta = "${datadir}/meta"
83 PACKAGES += "${PN}-meta"
84 PACKAGE_ARCH = "${MACHINE_ARCH}"
85
86 inherit autotools pkgconfig
87
88 EXTRA_OECONF = " \
89         BUILD_SYS=${BUILD_SYS} \
90         HOST_SYS=${HOST_SYS} \
91         STAGING_INCDIR=${STAGING_INCDIR} \
92         STAGING_LIBDIR=${STAGING_LIBDIR} \
93 "
94
95 python populate_packages_prepend () {
96         enigma2_plugindir = bb.data.expand('${libdir}/enigma2/python/Plugins', d)
97
98         do_split_packages(d, enigma2_plugindir, '(.*?/.*?)/.*', 'enigma2-plugin-%s', '%s ', recursive=True, match_path=True, prepend=True)
99 }
100
101 RCONFLICTS_${PN} = "dreambox-keymaps"
102 RREPLACES_${PN} = "dreambox-keymaps tuxbox-tuxtxt-32bpp (<= 0.0+cvs20090130-r1)"
103
104 # workaround for opkg <= 0.1.7+svnr455-r19.1
105 pkg_preinst_${PN} () {
106         if [ "x$D" != "x" ]; then
107                 exit 1
108         fi
109         if [ -f ${datadir}/fonts/tuxtxt.ttf ]; then
110                 cp -a ${datadir}/fonts/tuxtxt.ttf /tmp/tuxtxt.ttf
111         fi
112 }
113 pkg_postinst_${PN} () {
114         if [ "x$D" != "x" ]; then
115                 exit 1
116         fi
117         if [ -f /tmp/tuxtxt.ttf -a ! -f ${datadir}/fonts/tuxtxt.ttf ]; then
118                 mv /tmp/tuxtxt.ttf ${datadir}/fonts/tuxtxt.ttf
119         fi
120 }