meta-opendreambox/recipes-connectivity/madwifi/madwifi-ng_r3314-20080131.bb

   1 SRCREV = "30414"
   2 PR = "${INC_PR}.3"
   3
   4 # versions of OpenWrt backfire (10.03)
   5 HAL_VERSION = "20090508"
   6
   7 require madwifi-ng_r.inc
   8
   9 SRC_URI += " \
  10         svn://svn.openwrt.org/openwrt/trunk/package/madwifi;module=patches \
  11         http://mirror2.openwrt.org/sources/ath_hal-${HAL_VERSION}.tgz;name=hal \
  12         file://fix-target-mips32.patch \
  13         file://remove-wprobe.patch;apply=no \
  14         file://fix-module-autoload.patch;apply=no \
  15         file://fix-build-3.1.patch;apply=no \
  16         file://fix-build-3.2.patch;apply=no \
  17         file://ath-rate-ctlname.patch;apply=no \
  18         file://set-affinity-hint.patch;apply=no \
  19         file://workaround-high-interrupt-latency.patch;apply=no \
  20         file://madwifi-smp-affinity \
  21         "
  22 SRC_URI[md5sum] = "2c7352cbbdac995de8c3bce5b80db5f2"
  23 SRC_URI[sha256sum] = "0599c75b95ba63bdc554cb8124192e62c75fbeb71b9e8a5a7bc351c8e0666758"
  24 SRC_URI[hal.md5sum] = "4ab7ae8bdb96c0be388c98bf8f92d5ca"
  25 SRC_URI[hal.sha256sum] = "ced93d25aea7ee43807147a0269e69a072e718d59e7dab904bbe48b900409483"
  26
  27 addtask postpatch after do_patch before do_configure
  28
  29 do_postpatch() {
  30         rm -rf hal
  31         cp -a ${WORKDIR}/ath_hal-${HAL_VERSION} hal
  32         rm -f ${WORKDIR}/patches/104-autocreate_none.patch
  33         rm -f ${WORKDIR}/patches/446-single_module.patch
  34         rm -f ${WORKDIR}/patches/470-mac_addresss_from_ath5k_platform_data.patch
  35         for i in ${WORKDIR}/patches/*.patch; do
  36                 patch -p1 -i $i
  37         done
  38         patch -p1 -i ${WORKDIR}/remove-wprobe.patch
  39         patch -p1 -i ${WORKDIR}/fix-module-autoload.patch
  40         patch -p1 -i ${WORKDIR}/fix-build-3.1.patch
  41         patch -p1 -i ${WORKDIR}/fix-build-3.2.patch
  42         patch -p1 -i ${WORKDIR}/ath-rate-ctlname.patch
  43         patch -p1 -i ${WORKDIR}/set-affinity-hint.patch
  44         patch -p1 -i ${WORKDIR}/workaround-high-interrupt-latency.patch
  45 }
  46
  47 do_install_append() {
  48         install -d ${D}/etc/network/if-pre-up.d
  49         install -m 0755 ${WORKDIR}/madwifi-smp-affinity ${D}/etc/network/if-pre-up.d
  50         install -d ${D}/etc/network/if-post-down.d
  51         ln -sf ../if-pre-up.d/madwifi-smp-affinity ${D}/etc/network/if-post-down.d
  52 }