meta-opendreambox/recipes-dreambox/enigma2/enigma2-plugins_4.2.0.bb

   1 SUMMARY = "Additional plugins for Enigma2"
   2 LICENSE = "Proprietary"
   3 LIC_FILES_CHKSUM = "file://COPYING;md5=8e37f34d0e40d32ea2bc90ee812c9131"
   4 DEPENDS = " \
   5         dbttcd \
   6         dvdbackup \
   7         enigma2 \
   8         hdparm \
   9         python-daap \
  10         python-flickrapi \
  11         python-gdata \
  12         python-google-api-client \
  13         python-mutagen \
  14         python-pycrypto \
  15         python-pyopenssl \
  16         python-transmissionrpc \
  17         python-youtube-dl \
  18         smartmontools \
  19         streamripper \
  20 "
  21 SRCREV = "${@opendreambox_srcrev('f513b3ae5040236966b523fe51657c0b4f06b960', d)}"
  22
  23 SRC_URI += "file://print.mak"
  24
  25 inherit autotools schwerkraft-git pythonnative
  26
  27 export BUILD_SYS
  28 export HOST_SYS
  29 export STAGING_INCDIR
  30 export STAGING_LIBDIR
  31
  32 do_install_append() {
  33         # create lists of files installed outside of "${libdir}/enigma2/python/Plugins" or "${datadir}/meta"
  34         rm -rf ${INSTALL_ROOTDIR}
  35         install -d ${INSTALL_ROOTDIR}
  36         SUBDIRS=`make -f Makefile -f ${WORKDIR}/print.mak print-SUBDIRS`
  37         for SUBDIR in $SUBDIRS; do
  38                 oe_runmake -C $SUBDIR "DESTDIR=${INSTALL_DESTDIR}" install
  39                 CATEGORY=`ls -1 ${INSTALL_PLUGINSDIR} | head -n1 | tr '[:upper:]' '[:lower:]'`
  40                 NAME=`echo $SUBDIR | tr '[:upper:]' '[:lower:]'`
  41                 PKG="enigma2-plugin-$CATEGORY-$NAME"
  42                 rm -rf ${INSTALL_METADIR} ${INSTALL_PLUGINSDIR}
  43                 find ${INSTALL_DESTDIR} -type f -name "*.la" -delete -fprintf ${INSTALL_ROOTDIR}/$PKG-dev '/%P\n'
  44                 [ -s ${INSTALL_ROOTDIR}/$PKG-dev ] || rm ${INSTALL_ROOTDIR}/$PKG-dev
  45                 find ${INSTALL_DESTDIR} -type f -name "*.a" -delete -fprintf ${INSTALL_ROOTDIR}/$PKG-staticdev '/%P\n'
  46                 [ -s ${INSTALL_ROOTDIR}/$PKG-staticdev ] || rm ${INSTALL_ROOTDIR}/$PKG-staticdev
  47                 find ${INSTALL_DESTDIR} -type f -fprintf ${INSTALL_ROOTDIR}/$PKG '/%P\n'
  48                 [ -s ${INSTALL_ROOTDIR}/$PKG ] || rm ${INSTALL_ROOTDIR}/$PKG
  49                 rm -rf ${INSTALL_DESTDIR}
  50         done
  51 }
  52
  53 PACKAGES_DYNAMIC = "enigma2-plugin-*"
  54 PACKAGES += "${PN}-meta"
  55
  56 FILES_${PN} += "${datadir}/enigma2 ${datadir}/fonts"
  57 FILES_${PN}-meta = "${datadir}/meta"
  58
  59 python populate_packages_prepend() {
  60     enigma2_plugindir = bb.data.expand('${libdir}/enigma2/python/Plugins', d)
  61     do_split_packages(d, enigma2_plugindir, '^(\w+/\w+)', 'enigma2-plugin-%s', '%s', recursive=True, match_path=True, prepend=True)
  62     do_split_packages(d, enigma2_plugindir, '^(\w+/\w+).*/.*\.la$', 'enigma2-plugin-%s-dev', '%s (development)', recursive=True, match_path=True, prepend=True)
  63     do_split_packages(d, enigma2_plugindir, '^(\w+/\w+).*/.*\.a$', 'enigma2-plugin-%s-staticdev', '%s (static development)', recursive=True, match_path=True, prepend=True)
  64     do_split_packages(d, enigma2_plugindir, '^(\w+/\w+).*/\.debug/', 'enigma2-plugin-%s-dbg', '%s (debug)', recursive=True, match_path=True, prepend=True)
  65     def parseControlFile(dir, d, package):
  66         src = open(dir + "/" + package.split('-')[-1] + "/CONTROL/control").read()
  67         for line in src.splitlines():
  68             try:
  69                 name, value = line.strip().split(': ', 1)
  70                 if name == 'Description':
  71                     d.setVar('DESCRIPTION_' + package, value)
  72                 elif name == 'Depends':
  73                     d.setVar('RDEPENDS_' + package, ' '.join(value.split(', ')))
  74                 elif name == 'Replaces':
  75                     d.setVar('RREPLACES_' + package, ' '.join(value.split(', ')))
  76                 elif name == 'Conflicts':
  77                     d.setVar('RCONFLICTS_' + package, ' '.join(value.split(', ')))
  78             except:
  79                 bb.fatal("Error parsing control file for package %s" % package)
  80     def parseFileList(dir, d, package):
  81         filename = os.path.join(dir, package)
  82         if os.path.exists(filename):
  83             varname = 'FILES_%s' % package
  84             files = (d.getVar(varname, True) or "").split()
  85             src = open(filename).read()
  86             for line in src.splitlines():
  87                 if not line in files:
  88                     files.append(line)
  89             d.setVar(varname, ' '.join(files))
  90     tempdir = d.getVar('INSTALL_ROOTDIR', True)
  91     srcdir = d.getVar('S', True)
  92     for package in d.getVar('PACKAGES', True).split():
  93         if package.startswith('enigma2-plugin-'):
  94             parseFileList(tempdir, d, package)
  95             if not package.endswith('-dev') and not package.endswith('-dbg') and not package.endswith('-staticdev'):
  96                 parseControlFile(srcdir, d, package)
  97 }
  98
  99 INSTALL_ROOTDIR = "${WORKDIR}/${PN}-packaging-tempdir"
 100 INSTALL_DESTDIR = "${INSTALL_ROOTDIR}/destdir"
 101 INSTALL_METADIR = "${INSTALL_DESTDIR}${datadir}/meta"
 102 INSTALL_PLUGINSDIR = "${INSTALL_DESTDIR}${libdir}/enigma2/python/Plugins"
 103
 104 COMPATIBLE_MACHINE = "^(dm820|dm7080)$"