enigma2-plugins: add build dependency python-youtube-dl
[opendreambox.git] / meta-opendreambox / recipes-dreambox / enigma2 / enigma2-plugins_4.2.0.bb
1 SUMMARY = "Additional plugins for Enigma2"
2 LICENSE = "Proprietary"
3 LIC_FILES_CHKSUM = "file://COPYING;md5=8e37f34d0e40d32ea2bc90ee812c9131"
4 DEPENDS = " \
5         dbttcd \
6         dvdbackup \
7         enigma2 \
8         hdparm \
9         python-daap \
10         python-flickrapi \
11         python-gdata \
12         python-mutagen \
13         python-pycrypto \
14         python-pyopenssl \
15         python-transmissionrpc \
16         python-youtube-dl \
17         smartmontools \
18         streamripper \
19 "
20 SRCREV = "${@opendreambox_srcrev('0c3d98e38651e7e37d235fb57b90fecfd01ca151', d)}"
21
22 SRC_URI += "file://print.mak"
23
24 inherit autotools schwerkraft-git pythonnative
25
26 export BUILD_SYS
27 export HOST_SYS
28 export STAGING_INCDIR
29 export STAGING_LIBDIR
30
31 do_install_append() {
32         # create lists of files installed outside of "${libdir}/enigma2/python/Plugins" or "${datadir}/meta"
33         rm -rf ${INSTALL_ROOTDIR}
34         install -d ${INSTALL_ROOTDIR}
35         SUBDIRS=`make -f Makefile -f ${WORKDIR}/print.mak print-SUBDIRS`
36         for SUBDIR in $SUBDIRS; do
37                 oe_runmake -C $SUBDIR "DESTDIR=${INSTALL_DESTDIR}" install
38                 CATEGORY=`ls -1 ${INSTALL_PLUGINSDIR} | head -n1 | tr '[:upper:]' '[:lower:]'`
39                 NAME=`echo $SUBDIR | tr '[:upper:]' '[:lower:]'`
40                 PKG="enigma2-plugin-$CATEGORY-$NAME"
41                 rm -rf ${INSTALL_METADIR} ${INSTALL_PLUGINSDIR}
42                 find ${INSTALL_DESTDIR} -type f -name "*.la" -delete -fprintf ${INSTALL_ROOTDIR}/$PKG-dev '/%P\n'
43                 [ -s ${INSTALL_ROOTDIR}/$PKG-dev ] || rm ${INSTALL_ROOTDIR}/$PKG-dev
44                 find ${INSTALL_DESTDIR} -type f -name "*.a" -delete -fprintf ${INSTALL_ROOTDIR}/$PKG-staticdev '/%P\n'
45                 [ -s ${INSTALL_ROOTDIR}/$PKG-staticdev ] || rm ${INSTALL_ROOTDIR}/$PKG-staticdev
46                 find ${INSTALL_DESTDIR} -type f -fprintf ${INSTALL_ROOTDIR}/$PKG '/%P\n'
47                 [ -s ${INSTALL_ROOTDIR}/$PKG ] || rm ${INSTALL_ROOTDIR}/$PKG
48                 rm -rf ${INSTALL_DESTDIR}
49         done
50 }
51
52 PACKAGES_DYNAMIC = "enigma2-plugin-*"
53 PACKAGES += "${PN}-meta"
54
55 FILES_${PN} += "${datadir}/enigma2 ${datadir}/fonts"
56 FILES_${PN}-meta = "${datadir}/meta"
57
58 python populate_packages_prepend() {
59     enigma2_plugindir = bb.data.expand('${libdir}/enigma2/python/Plugins', d)
60     do_split_packages(d, enigma2_plugindir, '^(\w+/\w+)', 'enigma2-plugin-%s', '%s', recursive=True, match_path=True, prepend=True)
61     do_split_packages(d, enigma2_plugindir, '^(\w+/\w+).*/.*\.la$', 'enigma2-plugin-%s-dev', '%s (development)', recursive=True, match_path=True, prepend=True)
62     do_split_packages(d, enigma2_plugindir, '^(\w+/\w+).*/.*\.a$', 'enigma2-plugin-%s-staticdev', '%s (static development)', recursive=True, match_path=True, prepend=True)
63     do_split_packages(d, enigma2_plugindir, '^(\w+/\w+).*/\.debug/', 'enigma2-plugin-%s-dbg', '%s (debug)', recursive=True, match_path=True, prepend=True)
64     def parseControlFile(dir, d, package):
65         src = open(dir + "/" + package.split('-')[-1] + "/CONTROL/control").read()
66         for line in src.splitlines():
67             try:
68                 name, value = line.strip().split(': ', 1)
69                 if name == 'Description':
70                     d.setVar('DESCRIPTION_' + package, value)
71                 elif name == 'Depends':
72                     d.setVar('RDEPENDS_' + package, ' '.join(value.split(', ')))
73                 elif name == 'Replaces':
74                     d.setVar('RREPLACES_' + package, ' '.join(value.split(', ')))
75                 elif name == 'Conflicts':
76                     d.setVar('RCONFLICTS_' + package, ' '.join(value.split(', ')))
77             except:
78                 bb.fatal("Error parsing control file for package %s" % package)
79     def parseFileList(dir, d, package):
80         filename = os.path.join(dir, package)
81         if os.path.exists(filename):
82             varname = 'FILES_%s' % package
83             files = (d.getVar(varname, True) or "").split()
84             src = open(filename).read()
85             for line in src.splitlines():
86                 if not line in files:
87                     files.append(line)
88             d.setVar(varname, ' '.join(files))
89     tempdir = d.getVar('INSTALL_ROOTDIR', True)
90     srcdir = d.getVar('S', True)
91     for package in d.getVar('PACKAGES', True).split():
92         if package.startswith('enigma2-plugin-'):
93             parseFileList(tempdir, d, package)
94             if not package.endswith('-dev') and not package.endswith('-dbg') and not package.endswith('-staticdev'):
95                 parseControlFile(srcdir, d, package)
96 }
97
98 INSTALL_ROOTDIR = "${WORKDIR}/${PN}-packaging-tempdir"
99 INSTALL_DESTDIR = "${INSTALL_ROOTDIR}/destdir"
100 INSTALL_METADIR = "${INSTALL_DESTDIR}${datadir}/meta"
101 INSTALL_PLUGINSDIR = "${INSTALL_DESTDIR}${libdir}/enigma2/python/Plugins"
102
103 COMPATIBLE_MACHINE = "^(dm820|dm7080)$"