meta-opendreambox/recipes-dreambox/images/dreambox-rescue-image.bb

   1 inherit image
   2
   3 BAD_RECOMMENDATIONS += " \
   4         busybox-syslog \
   5         lighttpd-module-access \
   6         lighttpd-module-accesslog \
   7         udev-hwdb \
   8         update-rc.d \
   9 "
  10
  11 IMAGE_FEATURES = ""
  12 IMAGE_FSTYPES = "cpio"
  13 IMAGE_INSTALL = " \
  14         base-files \
  15         base-passwd \
  16         busybox \
  17         devnodes-minimal \
  18         ${@base_contains('MACHINE', 'dm520', 'dreambox-dvb-modules-stb-core', 'dreambox-dvb-modules-lcd', d)} \
  19         dropbear \
  20         e2fsprogs-e2fsck \
  21         google-dns \
  22         kmod \
  23         netbase \
  24         init-ifupdown \
  25         initscripts \
  26         modutils-initscripts \
  27         procps \
  28         recovery-ui \
  29         recovery-web \
  30         sysvinit \
  31         udev \
  32         xfsprogs-mkfs \
  33 "
  34 IMAGE_LINGUAS = ""
  35 IMAGE_ROOTFS_SIZE = "16384"
  36 USE_DEVFS = "1"
  37
  38 ISSUE_TEXT  = ">>> Your Dreambox has booted into RESCUE MODE.\n"
  39 ISSUE_TEXT .= ">>> Please log in as user 'root' (no password required),\n"
  40 ISSUE_TEXT .= ">>> then run 'help' to get further information.\n"
  41 ISSUE_TEXT .= "\n"
  42
  43 tweak_initramfs() {
  44         touch ${IMAGE_ROOTFS}${sysconfdir}/initrd-release
  45         sed -e '/enigma2/d' -i ${IMAGE_ROOTFS}${sysconfdir}/inittab
  46         printf "${ISSUE_TEXT}" >> ${IMAGE_ROOTFS}${sysconfdir}/issue
  47         printf "${ISSUE_TEXT}" >> ${IMAGE_ROOTFS}${sysconfdir}/issue.net
  48 }
  49
  50 ROOTFS_POSTPROCESS_COMMAND += "tweak_initramfs; "