#@TYPE: Distribution
#@NAME: OpenDreambox
#@DESCRIPTION: Distribution configuration for OpenDreambox

QA_LOG = "1"
#USER_CLASSES += "image-prelink"
INHERIT += "buildhistory recipe_sanity testlab"
BUILDHISTORY_COMMIT = "1"

DISTRO = "opendreambox"
DISTRO_NAME = "opendreambox"
DISTRO_VERSION = "2.0.0"
DISTRO_PR ?= ""

# meta/conf/distro/include/default-distrovars.inc
DISTRO_FEATURES += "3g alsa bluetooth directfb gtk-directfb ext2 largefile mplt nfs pci ppp smbfs usbhost zeroconf pci ${DISTRO_FEATURES_LIBC}"
DISTRO_FEATURES_BACKFILL_CONSIDERED = "pulseaudio"

# meta/recipes-core/tasks/task-core-boot.bb
DESCRIPTION_pn-task-core-boot = "opendreambox: minimal bootable image"
VIRTUAL-RUNTIME_dev_manager = "udev"
VIRTUAL-RUNTIME_login_manager = "busybox"
VIRTUAL-RUNTIME_init_manager = "sysvinit"
VIRTUAL-RUNTIME_initscripts = "initscripts"

# meta/recipes-core/sysvinit/sysvinit-inittab_2.88dsf.bb
SYSVINIT_ENABLED_GETTYS = ""

# meta/classes/image_types.bbclass
IMAGE_FSTYPES =+ "tar.bz2"

# package versions
OPENDREAMBOX_QT_VERSION = "4.8.1"

PREFERRED_VERSION_pango ?= "1.28.4"
PREFERRED_VERSION_qt4-embedded ?= "${OPENDREAMBOX_QT_VERSION}"
PREFERRED_VERSION_qt4-embedded-gles ?= "${OPENDREAMBOX_QT_VERSION}"
PREFERRED_VERSION_qt4-native ?= "${OPENDREAMBOX_QT_VERSION}"
PREFERRED_VERSION_qt4-tools-sdk ?= "${OPENDREAMBOX_QT_VERSION}"
PREFERRED_VERSION_qt4-x11-free = "${OPENDREAMBOX_QT_VERSION}"
PREFERRED_VERSION_qt4-x11-free-gles ?= "${OPENDREAMBOX_QT_VERSION}"
PREFERRED_VERSION_udev ?= "${@base_version_less_or_equal('DREAMBOX_KERNEL_VERSION', '2.6.26', '124', '182', d)}"
PREFERRED_VERSION_wpa-supplicant ?= "0.7.3"

PREFERRED_PROVIDER_jpeg = "jpeg"
PREFERRED_PROVIDER_jpeg-native = "jpeg-native"
PREFERRED_PROVIDER_libfribidi = "libfribidi"

PREFERRED_PROVIDERS += "virtual/${TARGET_PREFIX}gcc-initial:gcc-cross-initial"
PREFERRED_PROVIDERS += "virtual/${TARGET_PREFIX}gcc-intermediate:gcc-cross-intermediate"
PREFERRED_PROVIDERS += "virtual/${TARGET_PREFIX}gcc:gcc-cross"
PREFERRED_PROVIDERS += "virtual/${TARGET_PREFIX}g++:gcc-cross"

LICENSE_FLAGS_WHITELIST = "commercial_gst-plugins-ugly commercial_lame commercial_libmad commercial_mpeg2dec"
COMMERCIAL_AUDIO_PLUGINS ?= "gst-plugins-ugly-mad gst-plugins-ugly-mpegaudioparse"
COMMERCIAL_VIDEO_PLUGINS ?= "gst-plugins-ugly-mpeg2dec gst-plugins-ugly-mpegstream gst-plugins-bad-mpegvideoparse"

FULL_OPTIMIZATION = "-Os -pipe ${DEBUG_FLAGS}"
# build some core libs with better compiler optimization for better performance
O3_OPT = "-O3 -pipe ${DEBUG_FLAGS}"
FULL_OPTIMIZATION_pn-flac = "${O3_OPT}"
FULL_OPTIMIZATION_pn-jpeg = "${O3_OPT}"
FULL_OPTIMIZATION_pn-lame = "${O3_OPT}"
FULL_OPTIMIZATION_pn-liba52 = "${O3_OPT}"
FULL_OPTIMIZATION_pn-libdca = "${O3_OPT}"
FULL_OPTIMIZATION_pn-libgcrypt = "${O3_OPT}"
FULL_OPTIMIZATION_pn-libmad = "${O3_OPT}"
FULL_OPTIMIZATION_pn-libogg = "${O3_OPT}"
FULL_OPTIMIZATION_pn-libpng = "${O3_OPT}"
FULL_OPTIMIZATION_pn-libsamplerate = "${O3_OPT}"
FULL_OPTIMIZATION_pn-libvorbis = "${O3_OPT}"
FULL_OPTIMIZATION_pn-tremor = "${O3_OPT}"
FULL_OPTIMIZATION_pn-zlib = "${O3_OPT}"
PR_append_pn-flac = "-opt1"
PR_append_pn-jpeg = "-opt1"
PR_append_pn-lame = "-opt1"
PR_append_pn-liba52 = "-opt1"
PR_append_pn-libdca = "-opt1"
PR_append_pn-libgcrypt = "-opt1"
PR_append_pn-libmad = "-opt1"
PR_append_pn-libogg = "-opt1"
PR_append_pn-libpng = "-opt1"
PR_append_pn-libsamplerate = "-opt1"
PR_append_pn-libvorbis = "-opt1"
PR_append_pn-tremor = "-opt1"
PR_append_pn-zlib = "-opt1"

# Disable installing ldconfig
USE_LDCONFIG = "0"

TCLIBC = "eglibc"
TCLIBCAPPEND = ""

# Drop unused PACKAGE_EXTRA_ARCHS
PACKAGE_EXTRA_ARCHS = "${TUNE_PKGARCH}"

QEMU_TARGETS ?= "mipsel"

PREMIRRORS ?= "\
bzr://.*/.*   http://dreamboxupdate.com/sources-mirror/ \n \
cvs://.*/.*   http://dreamboxupdate.com/sources-mirror/ \n \
git://.*/.*   http://dreamboxupdate.com/sources-mirror/ \n \
hg://.*/.*    http://dreamboxupdate.com/sources-mirror/ \n \
osc://.*/.*   http://dreamboxupdate.com/sources-mirror/ \n \
p4://.*/.*    http://dreamboxupdate.com/sources-mirror/ \n \
svk://.*/.*   http://dreamboxupdate.com/sources-mirror/ \n \
svn://.*/.*   http://dreamboxupdate.com/sources-mirror/ \n \
bzr://.*/.*   http://autobuilder.yoctoproject.org/sources/ \n \
cvs://.*/.*   http://autobuilder.yoctoproject.org/sources/ \n \
git://.*/.*   http://autobuilder.yoctoproject.org/sources/ \n \
hg://.*/.*    http://autobuilder.yoctoproject.org/sources/ \n \
osc://.*/.*   http://autobuilder.yoctoproject.org/sources/ \n \
p4://.*/.*    http://autobuilder.yoctoproject.org/sources/ \n \
svk://.*/.*   http://autobuilder.yoctoproject.org/sources/ \n \
svn://.*/.*   http://autobuilder.yoctoproject.org/sources/ \n"

MIRRORS =+ "\
ftp://.*/.*    http://dreamboxupdate.com/sources-mirror/ \n \
http://.*/.*   http://dreamboxupdate.com/sources-mirror/ \n \
https://.*/.*  http://dreamboxupdate.com/sources-mirror/ \n \
ftp://.*/.*    http://autobuilder.yoctoproject.org/sources/ \n \
http://.*/.*   http://autobuilder.yoctoproject.org/sources/ \n \
https://.*/.*  http://autobuilder.yoctoproject.org/sources/ \n"

# for compatibility with rm_old_work.bbclass
WORKDIR = "${TMPDIR}/work/${MULTIMACH_TARGET_SYS}/${PN}/${PF}"