javasqlite 20080130: Added missing "+".
[openembedded.git] / packages / javasqlite / javasqlite_20080130.bb
1 DESCRIPTION = "JDBC driver for sqlite and sqlite3"
2 HOMEPAGE = "http://www.ch-werner.de/javasqlite"
3 LICENSE  = "BSD"
4
5 PR = "r2"
6
7 SRC_URI = "\
8   http://www.ch-werner.de/javasqlite/javasqlite-${PV}.tar.gz \
9   file://build-fix.patch;patch=1"
10
11 DEPENDS = "virtual/javac-native fastjar-native classpath-native javasqlite-mkconst-native classpath sqlite sqlite3"
12 RDEPENDS_${JPN} = "lib${PN}-jni"
13
14 inherit java-library autotools
15
16 JARFILENAME = "sqlite.jar"
17
18 # jamvm-native unfortunately contains non-generificed java/lang/reflect classes
19 # which are accessed in this package. Work around this by setting the bootclasspath
20 # explicitly.
21 export JAVACFLAGS="-bootclasspath ${STAGING_DATADIR}/classpath/glibj.zip -source 5.0"
22
23 EXTRA_OECONF = " \
24   --with-jni-incdir=${STAGING_INCDIR}/classpath \
25   --with-jardir=${datadir_java} \
26   --with-target-native-libdir=${libdir_jni} \
27   --with-sqlite-incdir=${STAGING_INCDIR} \
28   --with-sqlite-libdir=${STAGING_LIBDIR} \
29   --with-sqlite3-incdir=${STAGING_INCDIR} \
30   --with-sqlite3-libdir=${STAGING_LIBDIR} \
31   --with-java=${STAGING_BINDIR_NATIVE}/java \
32   --with-javac=${STAGING_BINDIR_NATIVE}/javac \
33   --with-jar=${STAGING_BINDIR_NATIVE}/gjar \
34   --with-javah=${STAGING_BINDIR_NATIVE}/gjavah \
35   --with-javadoc=true \
36   "
37
38 do_configurepre() {
39   sed -i -e "s|wrong-libtool|${TARGET_SYS}-libtool|" Makefile.in
40 }
41
42 addtask configurepre after do_patch before do_configure
43
44 do_compile_prepend() {
45   # Injects a cross-compiled mkconst binary into the build
46   cp ${STAGING_BINDIR_NATIVE}/javasqlite-mkconst-${PV} native/mkconst
47   touch native/mkconst
48 }
49
50 do_install_append() {
51   rm ${D}${libdir_jni}/libsqlite_jni.la
52   rm ${D}${libdir_jni}/libsqlite_jni.a
53 }
54
55 PACKAGES += "lib${PN}-jni lib${PN}-jni-dbg"
56
57 FILES_lib${PN}-jni = "${libdir_jni}/lib*.so*"
58 FILES_lib${PN}-jni-dbg = "${libdir_jni}/.debug/lib*.so*"